New Mail Notification for an Additional Mailbox – Part Three

The New Mail Notification for an Additional Mailbox solution I posted in December of 2010 has proven to be popular. I’ve gotten a couple of requests for modified version of the script, the most recent from Tom Hegh. Tom asked for the following modification

I have Outlook 2010, is it possible to get an notification the same as Outlook is showing ? this way, it’s not really a popup message which you have to click away. Reason I ask this question is that there also are a lot of notification mails, after a weekend, you have to click away about 200 e-mail popup messages, which also is not so pleasant.

The only way to provide a notification that looks and functions exactly like the one in Outlook 2010 would be to develop an add-in. That would require a fair amount of work and goes beyond what I’m prepared to do. I can however emulate the general behavior of Outlook’s notification dialog with the combination of a user-form and some additional code.

The user-form I’ll use is a simple dialog-box. The only control it requires is a textbox to display the notification message. The additional code will do two things. First, it will calculate the size of Tom’s screen in order to display the user-form right above the system tray just as Outlook’s notification window does. Second, it will add a timer that keeps the user-form onscreen for 2 seconds. That should be enough time for Tom to see it. When the 2 seconds expires the user-form will disappear automatically like the built-in notification. Unlike Outlook’s notification, this solution will not fade in and fade out, and will not offer options for opening or deleting the message. It will simply notify Tom that a message has arrived in the other mailbox.

Credit.

The code for detecting the size of the screen and working out the positioning of the user-form is based almost entirely on the code from this page.

The code for this comes in four parts.

Part 1.

Follow these instructions to add the user-form to Outlook.

1. Download the .zip file from this link
2. Unzip the file
3. Start Outlook
4. Press ALT+F11 to open the Visual Basic Editor
5. Click File and select Import File
6. Navigate to the folder you saved the files to in step #2
7. Select the file frmNotification

Part 2.

Follow these instructions to add this code to Outlook.

1. If not already expanded, expand Microsoft Office Outlook Objects
2. If not already expanded, expand Modules
3. Select an existing module (e.g. Module1) by double-clicking on it or create a new module by right-clicking Modules and selecting Insert > Module.
4. Copy the code from the Code Snippet box and paste it into the right-hand pane of Outlook’s VB Editor window
5. Edit the code as needed. I included comments wherever something needs to or can change
6. Click the diskette icon on the toolbar to save the changes
7. Close the VB Editor

'On the next line change the file name and path of the sound you want to play.'
Public Const SOUND_TO_PLAY = "C:\Windows\Media\Notify.wav"
Public Const SND_ASYNC = &H1
Public Const LOGPIXELSX = 88
Public Const LOGPIXELSY = 90
Public Const TWIPSPERINCH = 1440
Public Const SM_CXFULLSCREEN = 16
Public Const SM_CYFULLSCREEN = 17

Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Public Declare Function sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" _
(ByVal lpszSoundName As String, ByVal uFlags As Long) As Long
Public Declare Function MessageBox _
    Lib "User32" Alias "MessageBoxA" _
        (ByVal hWnd As Long, _
        ByVal lpText As String, _
        ByVal lpCaption As String, _
        ByVal wType As Long) _
    As Long
Public Declare Function GetDC Lib "user32" (ByVal hWnd As Long) As Long
Public Declare Function ReleaseDC Lib "user32" ( _
    ByVal hWnd As Long, _
    ByVal hDC As Long) As Long
Public Declare Function GetDeviceCaps Lib "gdi32" ( _
    ByVal hDC As Long, _
    ByVal nIndex As Long) As Long
Public Declare Function GetSystemMetrics Lib "user32" ( _
    ByVal nIndex As Long) As Long

Public Sub ConvertPixelsToPoints(ByRef X As Single, ByRef Y As Single)
    Dim hDC As Long
    Dim RetVal As Long
    Dim XPixelsPerInch As Long
    Dim YPixelsPerInch As Long

    hDC = GetDC(0)
    XPixelsPerInch = GetDeviceCaps(hDC, LOGPIXELSX)
    YPixelsPerInch = GetDeviceCaps(hDC, LOGPIXELSY)
    RetVal = ReleaseDC(0, hDC)
    X = X * TWIPSPERINCH / 20 / XPixelsPerInch
    Y = Y * TWIPSPERINCH / 20 / YPixelsPerInch
End Sub

Public Function OpenOutlookFolder(strFolderPath As String) As Outlook.MAPIFolder
    ' Purpose: Opens an Outlook folder from a folder path.'
    ' Written: 4/24/2009'
    ' Author:  BlueDevilFan'
    ' Outlook: All versions'
    Dim arrFolders As Variant, _
        varFolder As Variant, _
        bolBeyondRoot As Boolean
    On Error Resume Next
    If strFolderPath = "" Then
        Set OpenOutlookFolder = Nothing
    Else
        Do While Left(strFolderPath, 1) = "\"
            strFolderPath = Right(strFolderPath, Len(strFolderPath) - 1)
        Loop
        arrFolders = Split(strFolderPath, "\")
        For Each varFolder In arrFolders
            Select Case bolBeyondRoot
                Case False
                    Set OpenOutlookFolder = Outlook.Session.Folders(varFolder)
                    bolBeyondRoot = True
                Case True
                    Set OpenOutlookFolder = OpenOutlookFolder.Folders(varFolder)
            End Select
            If Err.Number <> 0 Then
                Set OpenOutlookFolder = Nothing
                Exit For
            End If
        Next
    End If
    On Error GoTo 0
End Function

Part 3.

Follow these instructions to add this code to Outlook.

1. If not already expanded, expand Microsoft Office Outlook Objects
2. Right-click on Class Modules, select Insert > Class Module
3. In the Properties panel click on Name and enter FolderMonitor
4. Copy the code from the Code Snippet box and paste it into the right-hand pane of Outlook’s VB Editor window
5. Edit the code as needed. I included comments wherever something needs to or can change
6. Click the diskette icon on the toolbar to save the changes

Private WithEvents olkItems As Outlook.Items
Private timStart As Date, _
        timEnd As Date, _
        sngHt As Single, _
        sngWt As Single, _
        objFrm As frmNotification

Private Sub Class_Initialize()
    sngWt = GetSystemMetrics(SM_CXFULLSCREEN) - 20
    sngHt = GetSystemMetrics(SM_CYFULLSCREEN) - 10
    ConvertPixelsToPoints sngWt, sngHt
    Set objFrm = New frmNotification
    objFrm.setScreen sngWt, sngHt
End Sub

Private Sub Class_Terminate()
    Set olkItems = Nothing
    Set objFrm = Nothing
End Sub

Public Sub FolderToWatch(objFolder As Outlook.Folder)
    Set olkItems = objFolder.Items
End Sub

Private Sub olkItems_ItemAdd(ByVal Item As Object)
    Dim lngHandle As Long, lngReturn As Long
    If (Time() >= timStart) And (Time <= timEnd) Then
        sndPlaySound SOUND_TO_PLAY, SND_ASYNC
        With objFrm
            .SetMsg "You have a new message!" & vbCrLf & "From: " & Item.SenderName & vbCrLf & "Subject: " & Item.Subject
            .ShowNotification
        End With
    End If
End Sub

Public Property Let ActivateAt(ByVal datValue As Date)
    timStart = datValue
End Property

Public Property Let DeactivateAt(ByVal datValue As Date)
    timEnd = datValue
End Property

Part 4.

Follow these instructions to add this code to Outlook.

1. If not already expanded, expand Microsoft Office Outlook Objects and click on ThisOutlookSession
2. Copy the code from the Code Snippet box and paste it into the right-hand pane of Outlook’s VB Editor window
3. Edit the code as needed. I included comment lines wherever something needs to or can change
4. Click the diskette icon on the toolbar to save the changes
5. Close the VB Editor
6. Click Tools > Trust Center
7. Click Macro Security
8. Set Macro Security to “Warnings for all macros”
9. Click OK
10. Close Outlook
11. Start Outlook. Outlook will display a dialog-box warning that ThisOutlookSession contains macros and asking if you want to allow them to run. Say yes.

Dim objFM1 As FolderMonitor
Dim objFM2 As FolderMonitor

Private Sub Application_Quit()
    Set objFM1 = Nothing
    Set objFM2 = Nothing
End Sub

Private Sub Application_Startup()
    Set objFM1 = New FolderMonitor
    With objFM1
        'Edit the folder path on the next line as needed.'
        .FolderToWatch OpenOutlookFolder("Mailbox - Doe, John\Inbox")
        'Set the times that monitoring should start/end'
        .ActivateAt = #12:00:00 AM#
        .DeactivateAt = #11:59:59 PM#
    End With
    Set objFM2 = New FolderMonitor
    With objFM2
        'Edit the folder path on the next line as needed.'
        .FolderToWatch OpenOutlookFolder("Mailbox - Brown, Bob\Inbox")
        'Set the times that monitoring should start/end'
        .ActivateAt = #10:00:00 PM#
        .DeactivateAt = #06:00:00 AM#
    End With
End Sub