Categorizing New Mail in Another Mailbox

In a comment to my New Mail Notification for an Additional Mailbox Tanveer asked if I could help him with some code to set a category on messages arriving in another mailbox’s inbox that meet a certain condition. Tanveer wants messages coming from the sender “Team@gmail.com” in the “Re-engineering Group” mailbox’s inbox assigned to the “Outgoing Email” category. Unfortunately this cannot by done by a rule as would be the case if the messages were arriving in the default mailbox. Rules only work on the default mailbox, not additional mailboxes or folders. Fortunately this is easily done by making a few modifications to the code from the original post. Here is that modified code.

The code for this comes in three parts.

Notes.

• If you are using the code from the first post, then you should already have the code from Part 1. You don’t need to add it again.
• If you are using the code from the first post, then you need to change the name of the class in step #3 of Part 2. You will also need to change “FolderMonitor” on lines 1 and 8 of Step 3 to match the class name. Finally, you will need to change the variable “objFM1” on lines 1, 8, and 10 of Step 3 to something new (e.g. objFM2).

Part 1.

Follow these instructions to add this code to Outlook.

1. Start Outlook
2. Click Tools > Macro > Visual Basic Editor
3. If not already expanded, expand Microsoft Office Outlook Objects
4. If not already expanded, expand Modules
5. Select an existing module (e.g. Module1) by double-clicking on it or create a new module by right-clicking Modules and selecting Insert > Module.
6. Copy the code from the Code Snippet box and paste it into the right-hand pane of Outlook’s VB Editor window
7. Edit the code as needed. I included comments wherever something needs to or can change
8. Click the diskette icon on the toolbar to save the changes
9. Close the VB Editor

Function OpenOutlookFolder(strFolderPath As String) As Outlook.MAPIFolder
    ' Purpose: Opens an Outlook folder from a folder path.'
    ' Written: 4/24/2009'
    ' Author:  BlueDevilFan'
    ' Outlook: All versions'
    Dim arrFolders As Variant, _
        varFolder As Variant, _
        bolBeyondRoot As Boolean
    On Error Resume Next
    If strFolderPath = "" Then
        Set OpenOutlookFolder = Nothing
    Else
        Do While Left(strFolderPath, 1) = "\"
            strFolderPath = Right(strFolderPath, Len(strFolderPath) - 1)
        Loop
        arrFolders = Split(strFolderPath, "\")
        For Each varFolder In arrFolders
            Select Case bolBeyondRoot
                Case False
                    Set OpenOutlookFolder = Outlook.Session.Folders(varFolder)
                    bolBeyondRoot = True
                Case True
                    Set OpenOutlookFolder = OpenOutlookFolder.Folders(varFolder)
            End Select
            If Err.Number <> 0 Then
                Set OpenOutlookFolder = Nothing
                Exit For
            End If
        Next
    End If
    On Error GoTo 0
End Function

Part 2.

Follow these instructions to add this code to Outlook.

1. If not already expanded, expand Microsoft Office Outlook Objects
2. Right-click on Class Modules, select Insert > Class
   Module
3. In the Properties panel click on Name and enter
   FolderMonitor
4. Copy the code from the Code Snippet box and paste it into the right-hand pane of Outlook’s VB Editor window
5. Edit the code as needed. I included comments wherever something needs to or can change
6. Click the diskette icon on the toolbar to save the changes

Private WithEvents olkItems As Outlook.Items

Private Sub Class_Terminate()
    Set olkFolder = Nothing
End Sub

Public Sub FolderToWatch(objFolder As Outlook.Folder)
    Set olkItems = objFolder.Items
End Sub

Private Sub olkItems_ItemAdd(ByVal Item As Object)
    If LCase(Item.SenderEmailAddress) = "team@gmail.com" then 
        Item.Categories = "Outgoing Email"
        Item.Save
    End If
End Sub

Part 3.

Follow these instructions to add this code to Outlook.

1. If not already expanded, expand Microsoft Office Outlook Objects and click on ThisOutlookSession
2. Copy the code from the Code Snippet box and paste it into the right-hand pane of Outlook’s VB Editor window
3. Edit the code as needed. I included comment lines wherever something needs to or can change
4. Click the diskette icon on the toolbar to save the changes
5. Close the VB Editor
6. Click Tools > Trust Center
7. Click Macro Security
8. Set Macro Security to “Warnings for all macros”
9. Click OK
10. Close Outlook
11. Start Outlook. Outlook will display a dialog-box warning that ThisOutlookSession contains macros and asking if you want to allow them to run. Say yes.

Dim objFM1 As FolderMonitor

Private Sub Application_Quit()
    Set objFM1 = Nothing
End Sub

Private Sub Application_Startup()
    Set objFM1 = New FolderMonitor
    'Edit the folder path on the next line as needed.'
    objFM1.FolderToWatch OpenOutlookFolder("Mailbox - Re-engineering Group\Inbox")
End Sub